Lazarus/Verzweigungen

Lazarus-Buch

• Einführung
• Technisches
• Komponenten, Eigenschaften, Ereignisse
• Computer-Mathematik
• Verzweigungen
• Spielen mit dem Zufall
• Schleifen
• Computer-Graphik
• Geschachtelte Verzweigungen und Verzweigungen in Schleifen
• Prozeduren, Funktionen und Bibliotheken
• Felder (Arrays)
• Zeichen (Char) und Zeichenkette (String)
• Dateien
• Graphische Komponenten

Wenn-Dann-Sonst (If-then-else)

Bisher wurden die Computerprogramme strikt von oben nach unten abgearbeitet. Das ist aber nicht immer wünschenswert. Zum Beispiel kann es sein, dass bestimmte Programmteile nur dann ausgeführt werden, wenn bestimmte Bedingungen auch erfüllt sind. Wir alle kennen z.B. Passwort-Abfragen, bei denen Funktionen eines Programms oder einer Website nur dann funktionieren, wenn man das richtige Passwort angibt.

Beispiel

Wir betrachten das einfache Beispiel eines Lazarus-Programms mit zwei Edit-Feldern, Edit1 und Edit2 und einem Button Button1. Wenn der Button1 gedrückt wird, soll der Computer die Eingabe in Edit1 überprüfen. Steht darin das richtige Passwort ("geheim"), so soll in Edit2 angezeigt werden: "Sie sind angemeldet!"

unit passwort;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,
  ExtCtrls;

type

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    Edit1: TEdit;
    Edit2: TEdit;
    procedure Button1Click(Sender: TObject);
  private
    { private declarations }
  public
    { public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.Button1Click(Sender: TObject);
begin
  if Edit1.Text='geheim'
  then Edit2.Text:='Sie sind angemeldet';
end;

end.

Das Programm ist allerdings noch nicht besonders benutzerfreundlich. Gibt der Benutzer z.B. ein falsches Passwort ein, so erhält er gar keine Nachricht. Es passiert einfach nichts.

Das kann man ändern. Im Falle, dass die Eingabe nicht 'geheim' lautet, soll in Edit2 die Bemerkung: 'Falsches Passwort' ausgegeben werden.

procedure TForm1.Button1Click(Sender: TObject);
begin
  if Edit1.Text='geheim'
  then Edit2.Text:='Sie sind angemeldet'
  else Edit2.Text:='Falsches Passwort';
end;

Wichtige Anmerkungen

• Achtung: vor "else" steht nie ein Semiklon. Das Semikolon beendet einen Befehl; die ganze If-then-else-Konstruktion ist jedoch im Grunde ein einzelner Befehl; das Semikolon steht erst danach.
• Man beachte das Gleichheitszeichen in if Edit1.Text='geheim'. Es ist ein einzelnes Gleichheitszeichen ohne Doppelpunkt. Es beschreibt auch etwas ganz anderes als eine Wertzuweisung: Es beschreibt einen Bedingung. Es gibt nur zwei Möglichkeiten: Die Bedingung ist erfüllt (wahr, engl. true) oder eben nicht (falsch, engl. false).
• Wenn Du Dich an das Kapitel Lazarus/Variablen_und_Komponenten erinnerst, kamen da Variablen vom Typ boolean vor, die genau diese beiden möglichen Werte hatten. Tatsächlich könnte man einer Variable b vom Typ boolean mit b:=(Edit1.Text='geheim'); einen Wert zuweisen, je nachdem, ob der Text der richtige war oder nicht.

Mehrere Anweisungen zu einem Block gruppieren

Bisher wird in jedem der beiden Fälle genau eine einzelne Anweisung ausgeführt. Es kann aber leicht sein, dass nur im Fall einer erfüllten (oder auch nicht erfüllten) Bedingung gleich mehrere Anweisungen ausgeführt werden sollen. Im nächsten Beispiel soll z.B. bei einer falschen Eingabe auf dem Button die Beschriftung zu 'Nochmal versuchen' geändert weden:

procedure TForm1.Button1Click(Sender: TObject);
begin
  if Edit1.Text='geheim'
  then Edit2.Text:='Sie sind angemeldet'
  else begin
       Edit2.Text:='Falsches Passwort';
       Button1.Caption:='Nochmal versuchen';
       end
end;

Die beiden Anweisungen zum Verändern von Edit2.Text und Button1.Caption sind durch ein begin und ein end umrahmt. Manche Leute sprechen von einem Programm-Block. Natürlich kann auch hinter then ein Programm-Block stehen: Aber Vorsicht: Hinter diesem end steht dann wieder kein Semikolon.

Vergleiche von Zahlen

Natürlich kann man nicht nur Zeichenketten miteinander vergleichen, sondern auch Zahlen. Neben der reinen Gleichheit gibt es auch andere Vergleichsoperatoren:

Vergleichsoperator	Bedeutung
=	gleich
<=	kleiner oder gleich
>=	größer oder gleich
<>	ungleich

Verknüpfung von Bedingungen

In einer if-Abfrage können auch Bedingungen abgefragt werden, die aus mehreren Teilbedingungen bestehen, die durch logische Verknüpfungen verbunden sind. Diese Verknüpfungen sind

Vergleichsoperator	Bedeutung
Bedingung1 and Bedingung2	Gilt dann und nur dann, wenn beide Bedingungen erfüllt sind.
Bedingung1 or Bedingung2	Gilt bereits dann, wenn eine der beiden Bedingungen erfüllt sind, aber auch dann, wenn beide erfüllt sind.
Bedingung1 xor Bedingung2	Gilt dann und nur dann, wenn genau eine der beiden Bedingungen erfüllt sind, aber nicht dann, wenn keine oder beide erfüllt sind.
not Bedingung	Gilt dann, wenn die Bedingung selbst genau nicht gilt.

Es ist generell sinnvoll, die einzelnen Bedingungen jeweils in Klammern zu setzen. Erstens erhöht es die Übersichtlichkeit und zweitens kann es bei fehlenden Klammern auch zu Problemen mit dem Compiler kommen.

Mehrfach-Fallunterscheidungen

Bisher wurde nur immer eine Bedingung geprüft und je nachdem ob sie erfüllt war (oder auch nicht) eine bestimmte Abfolge von Befehlen ausgeführt. Damit lassen sich im Grunde alle möglichen Abfragen realisieren, wenn auch manchmal recht umständlich. Angenommen, man wollte für einen Monat (angegeben wäre die Nummer des Monats im Jahr) wissen, wie viele Tage er hat (wir vernachlässigen Schaltjahre). Folgendes Programmstück könnte die Aufgabe lösen. Trotzdem erscheint es eben etwas umständlich mit den ganzen or-Verknüpfungen zwischen den Einzelbedingungen.

procedure TForm1.Button1Click(Sender: TObject);
var nummer, anzahltage : integer;
begin
  nummer:=StrToInt(Edit1.Text);
  if (nummer=2) then anzahltage:=28
  else   if ((nummer=4)
         or (nummer=6)
         or (nummer=9)
         or (nummer=11)) then anzahltage:=30
         else anzahltage:=31;
  label1.Caption:=IntToStr(anzahltage);
end;

Das Gleiche tut jedoch auch folgendes Programm, das für die Werte der Variablen "nummer" eine entsprechende Fallunterscheidung vornimmt.

procedure TForm1.Button1Click(Sender: TObject);
var nummer, anzahltage : integer;
begin
  nummer:=StrToInt(Edit1.Text);
  case nummer of
  2: anzahltage:=28;
  4,6,9,11 : anzahltage:=30;
  else anzahltage:=31;
  end; // Das "case" ist sozusagen das zugehörige "begin"
  label1.Caption:=IntToStr(anzahltage);
end;

Aufgaben

1. Abgestufte Höflichkeit
   In dem Edit-Feld Edit soll ein Vorname eingegeben werden. Wenn es Dein eigener ist, dann soll der Computer gehorsam mit "Willkommen mein Herr und Meister" begrüßen; ansonsten (etwas unfreundicher) mit "Was willst Du?".
2. Alltag: Volljährigkeit
   Ist der Bürger 18 Jahre und älter, dann ist er volljährig. Ein Computerprogramm soll auf Knopfdruck das Alter eines Bürgers aus dem Feld Edit1 einlesen und in das Feld Edit2 ausgeben, ob er volljährig ist.
3. Mathematik: Intervall-Prüfung
   Eine Zahl wird in einer Edit-Komponente eingegeben. Das Programm soll entscheiden, ob diese Zahl zwischen 10 und 20 liegt.
4. Informatik: Gefährliche Knöpfe
   Manche Aktionen bei Computerprogrammen sind so risikoreich, dass der Benutzer nicht einmal, sondern dreimal auf den entsprechenden Button klicken sollte, bevor sie ausgeführt werden. Schreibe ein Programm mit dem Knopf "Selbstzerstörung starten", den man drei mal drücken muss, bevor in einem Label der Text: "Selbstzerstörung ist aktiviert" erscheint und der Button selbst unsichtbar wird.
5. Mathematik: pq: Mission (im)possible
   Eine quadratische Funktion sei definiert als $f(x)=x^2+px+q$. Die so genannte pq-Formel gibt an, welche Nullstellen eine solche Funktion hat:
   $x_{1/2}=-\frac{p}{2}\pm\sqrt{\frac{p^2}{4}-q}$
   Ein Programm soll geschrieben werden, das die Werte p und q aus zwei Edit-Komponenten ausliest und in zwei weitere Edit-Komponenten die Werte der beiden Nullstellen schreibt. Vorausgesetzt natürlich, dass die Funktion überhaupt (reelle) Nullstellen hat (was nicht immer der Fall ist).
6. Alltag: Schaltjahr oder nicht
   Führe eine Internet-Recherche durch, wie man bei einer gegebenen Jahreszahl herausbekommen kann, ob es sich um ein Schaltjahr handelt oder nicht. Schreibe ein Programm, das nach Angabe einer Jahreszahl eine entsprechende Ausgabe zurückliefert.
7. Spiele: Farbe einer Roulette-Zahl
   Im Roulette-Spiel gibt es Zahlen zwischen 0 und 36. Die Null hat keine Farbe, sie ist einfach die Null (ZERO). Die Farben der anderen Zahlen sind mehr oder weniger willkürlich, aber schließlich gibt es Abbildungen von Roulette-Tischen im Internet. Schreibe ein Programm, das die Farbe zu einer eingegebenen Roulette-Zahl ermittelt.

Lazarus-Buch

• Einführung
• Technisches
• Komponenten, Eigenschaften, Ereignisse
• Computer-Mathematik
• Verzweigungen
• Spielen mit dem Zufall
• Schleifen
• Computer-Graphik
• Geschachtelte Verzweigungen und Verzweigungen in Schleifen
• Prozeduren, Funktionen und Bibliotheken
• Felder (Arrays)
• Zeichen (Char) und Zeichenkette (String)
• Dateien
• Graphische Komponenten